rcsfile(4)                                             rcsfile(4)



NAME
     rcsfile - format of an RCS file

DESCRIPTION
     An RCS file is an ASCII file.  Its content is  described  by
     the  grammar  below.   The  text  is  free  format; that is,
     spaces, tabs, and newlines have no  significance  except  in
     strings.   Strings  are enclosed by @.  If a string contains
     an @, it must be doubled.

     The metasyntax uses  the  following  conventions:   |  (bar)
     separates  alternatives; { and } enclose optional phrases; {
     and }* enclose phrases that may be  repeated  zero  or  more
     times;  {  and  }+ enclose phrases that must appear at least
     once and may be repeated; nonterminal  symbols  are  set  in
     italic font, and literals are set in a constant-width font.

     rcstext     ::=       admin {delta}* desc {deltatext}*

     admin       ::=       head     {num};
                           access   {id}*;
                           symbols  {id : num}*;
                           locks    {id : num}*;
                           comment  {string};

     delta       ::=       num
                           date     num;
                           author   id;
                           state    {id};
                           branches {num}*;
                           next     {num};

     desc        ::=       desc     string

     deltatext   ::=       num
                           log      string
                           text     string

     num         ::=       {digit{.}}+

     digit       ::=       0 | 1 | ... | 9

     id          ::=       letter{idchar}*

     letter      ::=       A | B | ... | Z | a | b | ... | z

     idchar      ::=       Any printing ASCII character except space,
                           tab, carriage return, newline, and special.

     special     ::=       ; | : | , | @

     string      ::=       @{any ASCII character, with @ doubled}*@



January 1992                                                    1

rcsfile(4)                                             rcsfile(4)



     Identifiers are case sensitive.  Keywords are  in  lowercase
     only.  The sets of keywords and identifiers may overlap.

     The delta nodes  form  a  tree.   All  nodes  whose  numbers
     consist  of  a single pair (2.3, 2.1, 1.3, and so forth) are
     on the trunk and are linked through the next field in  order
     of  decreasing  numbers.   The  head field in the admin node
     points to the head  of  that  sequence  which  contains  the
     highest pair.

     All delta nodes whose numbers consist  of  2n  fields  (n>2)
     (3.1.1.1, 2.1.2.2, and so forth) are linked as follows.  All
     nodes whose first (2n)-1 number  fields  are  identical  are
     linked  through  the  next  field  in  order  of  increasing
     numbers.  For each  such  sequence,  the  delta  node  whose
     number is identical to the first 2(n-1) number fields of the
     deltas on that sequence  is  called  the  branchpoint.   The
     branches  field  of a node contains a list of the numbers of
     the  first  nodes  of  all  sequences  for  which  it  is  a
     branchpoint.  This list is ordered in increasing numbers.

NOTES
     This reference manual entry describes a utility  that  Apple
     understands  to have been released into the public domain by
     its author or  authors.   Apple  has  included  this  public
     domain  utility  for  your  convenience.  Use it at your own
     discretion.  Often  the  source  code  can  be  obtained  if
     additional  requirements  are met, such as the purchase of a
     site license from an author or institution.

     Author: Walter F. Tichy, Purdue University, West  Lafayette,
     IN 47907.
               c
     Copyright   1982 by Walter F. Tichy.

SEE ALSO
     ci(1), co(1), ident(1), rcs(1), rcsdiff(1), rcsintro(1),
     rcsmerge(1), rlog(1) in A/UX Command Reference sccstorcs(1M)
     in A/UX System Administrator's Reference

















2                                                    January 1992